From e629bab292896e21f4c2f49cbd4b2c257cfd3b31 Mon Sep 17 00:00:00 2001
From: odrling <florianbadie@odrling.xyz>
Date: Tue, 4 Aug 2020 23:13:21 +0200
Subject: [PATCH] dev-libs/libratbag: add ebuild

---
 dev-libs/libratbag/Manifest              |  1 +
 dev-libs/libratbag/libratbag-0.14.ebuild | 83 ++++++++++++++++++++++++
 dev-libs/libratbag/metadata.xml          | 11 ++++
 3 files changed, 95 insertions(+)
 create mode 100644 dev-libs/libratbag/Manifest
 create mode 100644 dev-libs/libratbag/libratbag-0.14.ebuild
 create mode 100644 dev-libs/libratbag/metadata.xml

diff --git a/dev-libs/libratbag/Manifest b/dev-libs/libratbag/Manifest
new file mode 100644
index 0000000..f14dbca
--- /dev/null
+++ b/dev-libs/libratbag/Manifest
@@ -0,0 +1 @@
+DIST libratbag-0.14.tar.gz 244178 BLAKE2B adb3b98fd0892c1181a54a65a51bcd021af46ddddc4be14c69fe96aa3d8f22f813f545d3f3261ac84c538e3e55baba4375e2c5c4b46e2ac6ba45f3756c38a8dd SHA512 62a5029683d43ad9bb51433bc415e51d09169b9d5ed0955a7594fae61283475d77d1335b037c07a732ccdd05f06a55b87e76d4c701db9cdfeb35238d9edc4d02
diff --git a/dev-libs/libratbag/libratbag-0.14.ebuild b/dev-libs/libratbag/libratbag-0.14.ebuild
new file mode 100644
index 0000000..8364f61
--- /dev/null
+++ b/dev-libs/libratbag/libratbag-0.14.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_7 )
+inherit meson python-single-r1 udev
+
+DESCRIPTION="A DBus daemon to configure input devices, mainly high-end/gaming mice"
+HOMEPAGE="https://github.com/libratbag/libratbag"
+SRC_URI="https://github.com/libratbag/libratbag/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+systemd elogind doc test"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	( ^^ ( elogind systemd ) )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	elogind? ( >=sys-auth/elogind-227 )
+	systemd? ( >=sys-apps/systemd-227 )
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libunistring
+	dev-libs/libevdev
+	$(python_gen_cond_dep '
+		dev-python/python-evdev[${PYTHON_MULTI_USEDEP}]')
+	virtual/libudev
+"
+DEPEND="
+	${RDEPEND}
+	dev-lang/swig
+"
+BDEPEND="
+	virtual/pkgconfig
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+	')
+	doc? ( app-doc/doxygen )
+	test? (
+		>=dev-libs/check-0.9.10
+		$(python_gen_cond_dep '
+		dev-python/lxml[${PYTHON_MULTI_USEDEP}]')
+		dev-util/valgrind
+	)
+"
+
+src_prepare() {
+	default
+
+	python_setup
+	local pkgconfig_target="$(echo ${EPYTHON} | sed 's/python/python-/')"
+	sed -i "s/dependency('python3')/dependency('${pkgconfig_target}')/" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddocumentation=$(usex doc true false)
+		-Dtests=$(usex test true false)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+		-Dlogind-provider=$(usex elogind elogind systemd)
+		-Dsystemd=$(usex systemd true false)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+	python_fix_shebang "${ED}"/usr/bin/
+}
+
+pkg_postinst() {
+	elog 'Running ratbagd as DBus-activated systemd service:'
+	elog 'sudo systemctl daemon-reload'
+	elog 'sudo systemctl reload dbus.service'
+	elog 'sudo systemctl enable ratbagd.service'
+	elog 'sudo systemctl start ratbagd.service'
+}
diff --git a/dev-libs/libratbag/metadata.xml b/dev-libs/libratbag/metadata.xml
new file mode 100644
index 0000000..3f6ce26
--- /dev/null
+++ b/dev-libs/libratbag/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>silencly07@gmail.com</email>
+    <name>Petrus.Z</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">libratbag/libratbag</remote-id>
+  </upstream>
+</pkgmetadata>