dwm

x11-wm/dwm/dwm-9999.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit git-r3 toolchain-funcs
+
+DESCRIPTION="a dynamic window manager for X11"
+HOMEPAGE="https://dwm.suckless.org/"
+EGIT_REPO_URI="https://git.odrling.xyz/odrling/${PN}.git"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+IUSE="xinerama"
+
+RDEPEND="
+	media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXft
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="
+	${RDEPEND}
+	xinerama? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "s/ -Os / /" \
+		-e "/^\(LDFLAGS\|CFLAGS\|CPPFLAGS\)/{s| = | += |g;s|-s ||g}" \
+		config.mk || die
+}
+
+src_compile() {
+	if use xinerama; then
+		emake CC=$(tc-getCC) dwm
+	else
+		emake CC=$(tc-getCC) XINERAMAFLAGS="" XINERAMALIBS="" dwm
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/dwm-session2 dwm
+
+	insinto /usr/share/xsessions
+	doins "${FILESDIR}"/dwm.desktop
+
+	dodoc README
+}

x11-wm/dwm/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>florianbadie@odrling.xyz</email>
+</maintainer>
+<longdescription>
+dwm is a dynamic window manager for X. It manages windows in tiling and
+floating modes. Either mode can be applied dynamically, optimizing the
+environment for the application in use and the task performed.
+</longdescription>
+</pkgmetadata>